Matrix groups

Introduction

A matrix group is a group that consists of invertible square matrices over a common ring, the base ring of the group (see base_ring(G::MatrixGroup)).

We distinguish between matrices and elements of matrix groups, that is, matrix group elements are not regarded as matrices. This distinction is necessary because we want that each element of a matrix group has this group as its parent. An advantage of this setup is that we know more about a matrix group element than about a matrix, for example that it is square and invertible.

Apply matrix to the matrix group element $g$ in order to create the corresponding matrix $m$. Call $G(m)$ in order to create the group element corresponding to $m$.

julia> G = general_linear_group(3, 2)
GL(3,2)

julia> x, y = gens(G)
2-element Vector{MatrixGroupElem{FqFieldElem, FqMatrix}}:
 [1 1 0; 0 1 0; 0 0 1]
 [0 0 1; 1 0 0; 0 1 0]

julia> x
[1   1   0]
[0   1   0]
[0   0   1]

julia> m = matrix(x)
[1   1   0]
[0   1   0]
[0   0   1]

julia> m == x
false

julia> G(m) == x
true

julia> parent(x)
GL(3,2)

julia> parent(m)
Matrix space of 3 rows and 3 columns
  over prime field of characteristic 2

For convenience, functions for matrices such as det and tr are defined also for matrix group elements, see the section on functions for elements of matrix groups.

julia> det(x)
1

julia> tr(x)
1

Matrix groups in OSCAR have the type MatrixGroup{RE<:RingElem, T<:MatElem{RE}}, their elements have the type MatrixGroupElem{RE<:RingElem, T<:MatElem{RE}}.

Creation of matrix groups

The typical ways to create a matrix group are

to create matrices that generate the group, and then to call matrix_group with these generators, or
to start with a classical matrix group, and to create subgroups of it.

matrix_group — Method

matrix_group([R::Ring, m::Int, ]V::T...) where T<:Union{MatElem,MatrixGroupElem}
matrix_group([R::Ring, m::Int, ]V::AbstractVector{T}) where T<:Union{MatElem,MatrixGroupElem}

Return the matrix group generated by matrices in V. If V is empty then the base ring R and the degree m must be given.

Examples

julia> mats = [[0 -1; 1 -1], [0 1; 1 0]]
2-element Vector{Matrix{Int64}}:
 [0 -1; 1 -1]
 [0 1; 1 0]

julia> matelms = map(m -> matrix(ZZ, m), mats)
2-element Vector{ZZMatrix}:
 [0 -1; 1 -1]
 [0 1; 1 0]

julia> g = matrix_group(matelms)
Matrix group of degree 2
  over integer ring

julia> describe(g)
"S3"

julia> t = matrix_group(ZZ, 2, typeof(matelms[1])[])
Matrix group of degree 2
  over integer ring

julia> t == trivial_subgroup(g)[1]
true

julia> F = GF(3); matelms = map(m -> matrix(F, m), mats)
2-element Vector{FqMatrix}:
 [0 2; 1 2]
 [0 1; 1 0]

julia> g = matrix_group(matelms)
Matrix group of degree 2
  over prime field of characteristic 3

julia> describe(g)
"S3"