Creating Multivariate Rings

In this section, for the convenience of the reader, we recall from the chapters on rings and fields how to create multivariate polynomial rings and their elements, adding illustrating examples. At the same time, we introduce and illustrate a ring type for modelling multivariate polynomial rings with gradings.

Types

OSCAR provides types for dense univariate and sparse multivariate polynomials. The univariate ring types belong to the abstract type PolyRing{T}, their elements have abstract type PolyRingElem{T}. The multivariate ring types belong to the abstract type MPolyRing{T}, their elements have abstract type MPolyRingElem{T}. Here, T is the element type of the coefficient ring of the polynomial ring.

Constructors

The basic constructor below allows one to build multivariate polynomial rings:

polynomial_ring(C::Ring, xs::AbstractVector{<:VarName}; cached::Bool = true)

Given a ring C and a vector xs of Symbols, Strings, or Characters, return a tuple R, vars, say, which consists of a polynomial ring R with coefficient ring C and a vector vars of generators (variables) which print according to the entries of xs.

Note

Caching is used to ensure that a given ring constructed from given parameters is unique in the system. For example, there is only one ring of multivariate polynomials over $\mathbb{Z}$ with variables printing as x, y, z.

Examples

julia> R, (x, y, z) = polynomial_ring(ZZ, [:x, :y, :z])
(Multivariate polynomial ring in 3 variables over ZZ, ZZMPolyRingElem[x, y, z])

julia> typeof(R)
ZZMPolyRing

julia> typeof(x)
ZZMPolyRingElem

julia> S, (a, b, c) = polynomial_ring(ZZ, [:x, :y, :z])
(Multivariate polynomial ring in 3 variables over ZZ, ZZMPolyRingElem[x, y, z])

julia> T, _ = polynomial_ring(ZZ, [:x, :y, :z])
(Multivariate polynomial ring in 3 variables over ZZ, ZZMPolyRingElem[x, y, z])

julia> R === S === T
true

julia> R1, _ = polynomial_ring(ZZ, [:x, :y, :z]);

julia> R2, _ = polynomial_ring(ZZ, ["x", "y", "z"]);

julia> R3, _ = polynomial_ring(ZZ, ['x', 'y', 'z']);

julia> R1 === R2 === R3
true

julia> R1, x = polynomial_ring(QQ, [:x])
(Multivariate polynomial ring in 1 variable over QQ, QQMPolyRingElem[x])

julia> typeof(x)
Vector{QQMPolyRingElem} (alias for Array{QQMPolyRingElem, 1})

julia> R2, (x,) = polynomial_ring(QQ, [:x])
(Multivariate polynomial ring in 1 variable over QQ, QQMPolyRingElem[x])

julia> typeof(x)
QQMPolyRingElem

julia> R3, x = polynomial_ring(QQ, :x)
(Univariate polynomial ring in x over QQ, x)

julia> typeof(x)
QQPolyRingElem

julia> T, x = polynomial_ring(GF(3), ["x[1]", "x[2]"]);

julia> x
2-element Vector{FqMPolyRingElem}:
 x[1]
 x[2]

The constructor illustrated below allows for the convenient handling of variables with multi-indices:

julia> R, x, y, z = polynomial_ring(QQ, :x => (1:3, 1:4), :y => 1:2, :z => (1:1, 1:1, 1:1));

julia> x
3×4 Matrix{QQMPolyRingElem}:
 x[1, 1]  x[1, 2]  x[1, 3]  x[1, 4]
 x[2, 1]  x[2, 2]  x[2, 3]  x[2, 4]
 x[3, 1]  x[3, 2]  x[3, 3]  x[3, 4]

julia> y
2-element Vector{QQMPolyRingElem}:
 y[1]
 y[2]

julia> z
1×1×1 Array{QQMPolyRingElem, 3}:
[:, :, 1] =
 z[1, 1, 1]

Coefficient Rings

Gröbner and standard bases are implemented for multivariate polynomial rings over the fields and rings below:

The Field of Rational Numbers $\mathbb{Q}$

julia> QQ
Rational field

Number Fields

julia> Qx, x = QQ["x"];

julia> K, a = number_field(x^2 - 5, "a")
(Number field of degree 2 over QQ, a)

julia> Kt, t = K["t"];

julia> L, b = number_field(t^3 - 3, "b")
(Relative number field of degree 3 over K, b)

julia> Qx, x = QQ["x"];

julia> julia> L, a = number_field([x^2 - 5, x^3 - 3], "a")
(Non-simple number field of degree 6 over QQ, AbsNonSimpleNumFieldElem[a1, a2])

julia> K, a = quadratic_field(5)
(Real quadratic field defined by x^2 - 5, sqrt(5))

julia> K, zeta = cyclotomic_field(3) 
(Cyclotomic field of order 3, z_3)

The Abelian Closure of $\mathbb{Q}$

julia> K, z = abelian_closure(QQ)
(Abelian closure of rational field, Generator of abelian closure of rational field)

julia> F = algebraic_closure(QQ)
Algebraic closure of rational field

julia> z(3)*z(5)
zeta(15)^7 - zeta(15)^5 + zeta(15)^4 - zeta(15)^3 + zeta(15) - 1

Finite Fields

julia> GF(3)
Prime field of characteristic 3

julia> GF(ZZ(2)^127 - 1)
Prime field of characteristic 170141183460469231731687303715884105727

julia> GF(3,2)
Finite field of degree 2 and characteristic 3

julia> GF(3,2) == GF(9)
true

julia> F, a = finite_field(2, 70, "a")
(Finite field of degree 70 and characteristic 2, a)

julia> K, a = finite_field(9, "a")
(Finite field of degree 2 and characteristic 3, a)

julia> Kx, x = K["x"];

julia> L, b = finite_field(x^3 + x^2 + x + 2, "b")
(Finite field of degree 3 over K, b)

Algebraic Closures of Prime Fields

julia> K = algebraic_closure(GF(3))
Algebraic closure of prime field of characteristic 3

julia> L = algebraic_closure(QQ)
Algebraic closure of rational field

Rational Function Fields

julia> R, (x, y) = rational_function_field(QQ, [:x, :y])
(Rational function field over QQ, AbstractAlgebra.Generic.RationalFunctionFieldElem{QQFieldElem, QQMPolyRingElem}[x, y])

Function Fields of Transcendence Degree 1

julia> K = GF(101)
Prime field of characteristic 101

julia> Kx, x = rational_function_field(K, :x)
(Rational function field over K, x)

julia> Kxy, y = polynomial_ring(Kx, :y)
(Univariate polynomial ring in y over Kx, y)

julia> F, a = function_field(x^3-y^2)
(Function Field over K with defining polynomial 100*_a^2 + x^3, _a)

The Ring of Integers $\mathbb{Z}$

julia> ZZ
Integer ring

Rings of Type $\mathbb{Z}/m\mathbb{Z}$

julia> quo(ZZ, ZZ(6))[1]
Integers modulo 6

Gradings

Given a polynomial ring $R = C[x_1, \dots, x_n]$, we may endow $R$ with various gradings. The standard $\mathbb Z$-grading on $R$ is the decomposition $R=\bigoplus_{d\in \mathbb Z} R_d=\bigoplus_{d\geq 0} R_d$ by the usual degree of polynomials. More general $\mathbb Z$-gradings are obtained by assigning integer weights to the variables and considering the corresponding weighted degrees. Even more generally, we may consider multigradings: Given a finitely generated abelian group $G$, a multigrading on $R$ by $G$, or a $G$-grading, or simply a grading, corresponds to a semigroup homomorphism $\phi: \mathbb N^n \to G$: Given $\phi$, the degree of a monomial $x^\alpha$ is the image $\deg(x^\alpha):=\phi(\alpha)\in G$; the induced $G$-grading on $R$ is the decomposition $R = \bigoplus_{g\in G} R_g$ satisfying $R_g\cdot R_h\subset R_{g+h}$, where $R_g$ is the free $C$-module generated by the monomials of degree $g$. This grading is determined by assigning the weights $\deg(x_i)$ to the $x_i$. In other words, it is determined by the weight vector $W = (\deg(x_1), \dots, \deg(x_n))\in G^n.$

We refer to the textbooks [MS05] and [KR05] for details on multigradings. With respect to notation, we follow the former book.

Note

Given a $G$-grading on $R$, we refer to $G$ as the grading group of $R$. Moreover, we then say that $R$ is $G$-graded, or simply that $R$ is graded. If $R$ is a polynomial ring over a field, we say that a $G$-grading on $R$ is positive if $G$ is free and each graded part $R_g$, $g\in G$, has finite dimension. We then also say that $R$ is positively graded (by $G$). Note that the positivity condition can be equivalently expressed by asking that $G$ is free and that the degree zero part consists of the constants only (see Theorem 8.6 in [MS05]).

Note

Given a G-grading on R in OSCAR, we say that R is $\mathbb Z^m$-graded if is_free(G) && number_of_generators(G) == rank(G) == m evaluates to true. In this case, conversion routines allow one to switch back and forth between elements of G and integer vectors of length m. Specifically, if R is $\mathbb Z$-graded, that is, is_free(G) && number_of_generators(G) == rank(G) == 1 evaluates to true, elements of G may be converted to integers and vice versa.

Types

Multivariate rings with gradings are modeled by objects of type MPolyDecRing{T, S} :< MPolyRing{T}, with elements of type MPolyRingElem_dec{T, S} :< MPolyRingElem{T}. Here, S is the element type of the multivariate ring, and T is the element type of its coefficient ring as above.

Note

The types MPolyDecRing{T, S} and MPolyRingElem_dec{T, S} are also meant to eventually model multivariate rings with filtrations and their elements.

The following function allows one, in particular, to distinguish between graded and filtered rings.

is_graded — Method

is_graded(R::MPolyRing)

Return true if R is graded, false otherwise.