# Sparse distributed multivariate polynomials

AbstractAlgebra.jl provides a module, implemented in `src/MPoly.jl`

for sparse distributed multivariate polynomials over any commutative ring belonging to the AbstractAlgebra abstract type hierarchy.

## Generic sparse distributed multivariable polynomial types

AbstractAlgebra provides a generic multivariate polynomial type `Generic.MPoly{T}`

where `T`

is the type of elements of the coefficient ring.

The polynomials are implemented using a Julia array of coefficients and a 2-dimensional Julia array of `UInt`

s for the exponent vectors. Note that exponent $n$ is represented by the $n$-th column of the exponent array, not the $n$-th row. This is because Julia uses a column major representation. See the file `src/generic/GenericTypes.jl`

for details.

The top bit of each `UInt`

is reserved for overflow detection.

Parent objects of such polynomials have type `Generic.MPolyRing{T}`

.

The string representation of the variables of the polynomial ring and the base/coefficient ring $R$ and the ordering are stored in the parent object.

## Abstract types

The polynomial element types belong to the abstract type `MPolyElem{T}`

and the polynomial ring types belong to the abstract type `MPolyRing{T}`

.

Note that both the generic polynomial ring type `Generic.MPolyRing{T}`

and the abstract type it belongs to, `MPolyRing{T}`

are both called `MPolyRing`

. The former is a (parameterised) concrete type for a polynomial ring over a given base ring whose elements have type `T`

. The latter is an abstract type representing all multivariate polynomial ring types in AbstractAlgebra.jl, whether generic or very specialised (e.g. supplied by a C library).

## Polynomial ring constructors

In order to construct multivariate polynomials in AbstractAlgebra.jl, one must first construct the polynomial ring itself. This is accomplished with one of the following constructors.

`PolynomialRing`

— Method`PolynomialRing(R::AbstractAlgebra.Ring, s::Vector{T}; cached::Bool = true, ordering::Symbol = :lex) where T <: Union{String, Char, Symbol}`

Given a base ring `R`

and an array of strings `s`

specifying how the generators (variables) should be printed, return a tuple `T, (x1, x2, ...)`

representing the new polynomial ring $T = R[x1, x2, ...]$ and the generators $x1, x2, ...$ of the polynomial ring. By default the parent object `T`

will depend only on `R`

and `x1, x2, ...`

and will be cached. Setting the optional argument `cached`

to `false`

will prevent the parent object `T`

from being cached. `S`

is a symbol corresponding to the ordering of the polynomial and can be one of `:lex`

, `:deglex`

or `:degrevlex`

.

`PolynomialRing`

— Method`PolynomialRing(R::Ring, n::Int, s::String; cached::Bool = false, ordering::Symbol = :lex)`

Given a string `s`

and a number of variables `n`

will do the same as the first constructor except that the variables will be automatically numbered. For example if `s`

is the string `x`

and `n = 3`

then the variables will print as `x1`

, `x2`

, `x3`

.

By default the parent object `S`

will depend only on `R`

and `(x, ...)`

and will be cached. Setting the optional argument `cached`

to `false`

will prevent the parent object `S`

from being cached.

The optional named argument `ordering`

can be used to specify an ordering. The currently supported options are `:lex`

, `:deglex`

and `:degrevlex`

.

Like for univariate polynomials, a shorthand constructor is provided when the number of generators is greater than `1`

: given a base ring `R`

, we abbreviate the constructor as follows:

`R["x", "y", ...]`

Here are some examples of creating multivariate polynomial rings and making use of the resulting parent objects to coerce various elements into the polynomial ring.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"]; ordering=:deglex)
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> T, (z, t) = QQ["z", "t"]
(Multivariate Polynomial Ring in z, t over Rationals, AbstractAlgebra.Generic.MPoly{Rational{BigInt}}[z, t])
julia> f = R()
0
julia> g = R(123)
123
julia> h = R(BigInt(1234))
1234
julia> k = R(x + 1)
x + 1
julia> m = R(x + y + 1)
x + y + 1
julia> derivative(k, 1)
1
julia> derivative(k, 2)
0
```

## Polynomial constructors

Multivariate polynomials can be constructed from the generators in the usual way using arithmetic operations.

Also, all of the standard ring element constructors may be used to construct multivariate polynomials.

```
(R::MPolyRing{T})() where T <: RingElement
(R::MPolyRing{T})(c::Integer) where T <: RingElement
(R::MPolyRing{T})(a::elem_type(R)) where T <: RingElement
(R::MPolyRing{T})(a::T) where T <: RingElement
```

For more efficient construction of multivariate polynomial, one can use the `MPoly`

build context, where terms (coefficient followed by an exponent vector) are pushed onto a context one at a time and then the polynomial constructed from those terms in one go using the `finish`

function.

`MPolyBuildCtx`

— Method`MPolyBuildCtx(R::MPolyRing)`

Return a build context for creating polynomials in the given ring.

`push_term!`

— Method`push_term!(M::MPolyBuildCtx, c::RingElem, v::Vector{Int})`

Add the term with coefficient `c`

and exponent vector `v`

to the polynomial under construction in the build context `M`

.

`finish`

— Method`finish(M::MPolyBuildCtx)`

Finish construction of the polynomial, sort the terms, remove duplicate and zero terms and return the created polynomial.

Note that the `finish`

function resets the build context so that it can be used to construct multiple polynomials..

When a multivariate polynomial type has a representation that allows constant time access (e.g. it is represented internally by arrays), the following additional constructor is available. It takes and array of coefficients and and array of exponent vectors.

`(S::MPolyRing{T})(A::Vector{T}, m::Vector{Vector{Int}}) where T <: RingElem`

Create the polynomial in the given ring with nonzero coefficients specified by the elements of $A$ and corresponding exponent vectors given by the elements of $m$.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> C = MPolyBuildCtx(R)
Builder for an element of Multivariate Polynomial Ring in x, y over Integers
julia> push_term!(C, ZZ(3), [1, 2]);
julia> push_term!(C, ZZ(2), [1, 1]);
julia> push_term!(C, ZZ(4), [0, 0]);
julia> f = finish(C)
3*x*y^2 + 2*x*y + 4
julia> push_term!(C, ZZ(4), [1, 1]);
julia> f = finish(C)
4*x*y
julia> S, (x, y) = PolynomialRing(QQ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Rationals, AbstractAlgebra.Generic.MPoly{Rational{BigInt}}[x, y])
julia> f = S(Rational{BigInt}[2, 3, 1], [[3, 2], [1, 0], [0, 1]])
2*x^3*y^2 + 3*x + y
```

## Functions for types and parents of multivariate polynomial rings

```
base_ring(R::MPolyRing)
base_ring(a::MPolyElem)
```

Return the coefficient ring of the given polynomial ring or polynomial, respectively.

`parent(a::MPolyElem)`

Return the polynomial ring of the given polynomial.

`characteristic(R::MPolyRing)`

Return the characteristic of the given polynomial ring. If the characteristic is not known, an exception is raised.

## Polynomial functions

### Basic manipulation

All the standard ring functions are available, including the following.

```
zero(R::MPolyRing)
one(R::MPolyRing)
iszero(a::MPolyElem)
isone(a::MPolyElem)
```

`divexact(a::T, b::T) where T <: MPolyElem`

All basic functions from the Multivariate Polynomial interface are provided.

```
symbols(S::MPolyRing)
nvars(f::MPolyRing)
gens(S::MPolyRing)
gen(S::MPolyRing, i::Int)
```

`ordering(S::MPolyRing{T})`

Note that the currently supported orderings are `:lex`

, `:deglex`

and `:degrevlex`

.

```
length(f::MPolyElem)
degrees(f::MPolyElem)
total_degree(f::MPolyElem)
```

`is_gen(x::MPolyElem)`

`divexact(f::T, g::T) where T <: MPolyElem`

For multivariate polynomial types that allow constant time access to coefficients, the following are also available, allowing access to the given coefficient, monomial or term. Terms are numbered from the most significant first.

```
coeff(f::MPolyElem, n::Int)
coeff(a::MPolyElem, exps::Vector{Int})
```

Access a coefficient by term number or exponent vector.

```
monomial(f::MPolyElem, n::Int)
monomial!(m::T, f::T, n::Int) where T <: MPolyElem
```

The second version writes the result into a preexisting polynomial object to save an allocation.

`term(f::MPolyElem, n::Int)`

`exponent(f::MyMPolyElem, i::Int, j::Int)`

Return the exponent of the $j$-th variable in the $i$-th term of the polynomial $f$.

`exponent_vector(a::MPolyElem, i::Int)`

`setcoeff!(a::MPolyElem{T}, exps::Vector{Int}, c::T) where T <: RingElement`

Although multivariate polynomial rings are not usually Euclidean, the following functions from the Euclidean interface are often provided.

```
divides(f::T, g::T) where T <: MPolyElem
remove(f::T, g::T) where T <: MPolyElem
valuation(f::T, g::T) where T <: MPolyElem
```

```
divrem(f::T, g::T) where T <: MPolyElem
div(f::T, g::T) where T <: MPolyElem
```

Compute a tuple $(q, r)$ such that $f = qg + r$, where the coefficients of terms of $r$ whose monomials are divisible by the leading monomial of $g$ are reduced modulo the leading coefficient of $g$ (according to the Euclidean function on the coefficients). The `divrem`

version returns both quotient and remainder whilst the `div`

version only returns the quotient.

Note that the result of these functions depend on the ordering of the polynomial ring.

`gcd(f::T, g::T) where T <: MPolyElem`

The following functionality is also provided for all multivariate polynomials.

`is_univariate`

— Method`is_univariate(R::AbstractAlgebra.MPolyRing)`

Returns `true`

if $R$ is a univariate polynomial ring, i.e. has exactly one variable, and `false`

otherwise.

`vars`

— Method`vars(p::AbstractAlgebra.MPolyElem{T}) where {T <: RingElement}`

Return the variables actually occurring in $p$.

`var_index`

— Method`var_index(p::AbstractAlgebra.MPolyElem{T}) where {T <: RingElement}`

Return the index of the given variable $x$. If $x$ is not a variable in a multivariate polynomial ring, an exception is raised.

`degree`

— Method`degree(f::AbstractAlgebra.MPolyElem{T}, i::Int) where T <: RingElement`

Return the degree of the polynomial $f$ in terms of the i-th variable.

`degree`

— Method`degree(f::AbstractAlgebra.MPolyElem{T}, x::AbstractAlgebra.MPolyElem{T}) where T <: RingElement`

Return the degree of the polynomial $f$ in terms of the variable $x$.

`degrees`

— Method`degrees(f::AbstractAlgebra.MPolyElem{T}) where T <: RingElement`

Return an array of the degrees of the polynomial $f$ in terms of each variable.

`is_constant`

— Method`is_constant(x::AbstractAlgebra.MPolyElem{T}) where T <: RingElement`

Return `true`

if `x`

is a degree zero polynomial or the zero polynomial, i.e. a constant polynomial.

`is_term`

— Method`is_term(x::MPoly)`

Return `true`

if the given polynomial has precisely one term.

`is_monomial`

— Method`is_monomial(x::AbstractAlgebra.MPolyElem)`

Return `true`

if the given polynomial has precisely one term whose coefficient is one.

`is_univariate`

— Method`is_univariate(p::AbstractAlgebra.MPolyElem)`

Returns `true`

if $p$ is a univariate polynomial, i.e. involves at most one variable (thus constant polynomials are considered univariate), and `false`

otherwise. The result depends on the terms of the polynomial, not simply on the number of variables in the polynomial ring.

`coeff`

— Method`coeff(f::AbstractAlgebra.MPolyElem{T}, m::AbstractAlgebra.MPolyElem{T}) where T <: RingElement`

Return the coefficient of the monomial $m$ of the polynomial $f$. If there is no such monomial, zero is returned.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = x^2 + 2x + 1
x^2 + 2*x + 1
julia> V = vars(f)
1-element Vector{AbstractAlgebra.Generic.MPoly{BigInt}}:
x
julia> var_index(y) == 2
true
julia> degree(f, x) == 2
true
julia> degree(f, 2) == 0
true
julia> d = degrees(f)
2-element Vector{Int64}:
2
0
julia> is_constant(R(1))
true
julia> is_term(2x)
true
julia> is_monomial(y)
true
julia> is_unit(R(1))
true
julia> S, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = x^3*y + 3x*y^2 + 1
x^3*y + 3*x*y^2 + 1
julia> c1 = coeff(f, 1)
1
julia> c2 = coeff(f, x^3*y)
1
julia> m = monomial(f, 2)
x*y^2
julia> e1 = exponent(f, 1, 1)
3
julia> v1 = exponent_vector(f, 1)
2-element Vector{Int64}:
3
1
julia> t1 = term(f, 1)
x^3*y
julia> setcoeff!(f, [3, 1], 12)
12*x^3*y + 3*x*y^2 + 1
julia> S, (x, y) = PolynomialRing(QQ, ["x", "y"]; ordering=:deglex)
(Multivariate Polynomial Ring in x, y over Rationals, AbstractAlgebra.Generic.MPoly{Rational{BigInt}}[x, y])
julia> V = symbols(S)
2-element Vector{Symbol}:
:x
:y
julia> X = gens(S)
2-element Vector{AbstractAlgebra.Generic.MPoly{Rational{BigInt}}}:
x
y
julia> ord = ordering(S)
:deglex
julia> S, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = x^3*y + 3x*y^2 + 1
x^3*y + 3*x*y^2 + 1
julia> n = length(f)
3
julia> is_gen(y)
true
julia> nvars(S) == 2
true
julia> d = total_degree(f)
4
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = 2x^2*y + 2x + y + 1
2*x^2*y + 2*x + y + 1
julia> g = x^2*y^2 + 1
x^2*y^2 + 1
julia> flag, q = divides(f*g, f)
(true, x^2*y^2 + 1)
julia> d = divexact(f*g, f)
x^2*y^2 + 1
julia> v, q = remove(f*g^3, g)
(3, 2*x^2*y + 2*x + y + 1)
julia> n = valuation(f*g^3, g)
3
julia> R, (x, y) = PolynomialRing(QQ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Rationals, AbstractAlgebra.Generic.MPoly{Rational{BigInt}}[x, y])
julia> f = 3x^2*y^2 + 2x + 1
3*x^2*y^2 + 2*x + 1
julia> f1 = divexact(f, 5)
3//5*x^2*y^2 + 2//5*x + 1//5
julia> f2 = divexact(f, QQ(2, 3))
9//2*x^2*y^2 + 3*x + 3//2
```

### Square root

Over rings for which an exact square root is available, it is possible to take the square root of a polynomial or test whether it is a square.

```
sqrt(f::MPolyElem, check::bool=true)
is_square(::MPolyElem)
```

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = -4*x^5*y^4 + 5*x^5*y^3 + 4*x^4 - x^3*y^4
-4*x^5*y^4 + 5*x^5*y^3 + 4*x^4 - x^3*y^4
julia> sqrt(f^2)
4*x^5*y^4 - 5*x^5*y^3 - 4*x^4 + x^3*y^4
julia> is_square(f)
false
```

### Iterators

The following iterators are provided for multivariate polynomials.

```
coefficients(p::MPoly)
monomials(p::MPoly)
terms(p::MPoly)
exponent_vectors(a::MPoly)
```

**Examples**

```
julia> S, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = x^3*y + 3x*y^2 + 1
x^3*y + 3*x*y^2 + 1
julia> C = collect(coefficients(f))
3-element Vector{BigInt}:
1
3
1
julia> M = collect(monomials(f))
3-element Vector{AbstractAlgebra.Generic.MPoly{BigInt}}:
x^3*y
x*y^2
1
julia> T = collect(terms(f))
3-element Vector{AbstractAlgebra.Generic.MPoly{BigInt}}:
x^3*y
3*x*y^2
1
julia> V = collect(exponent_vectors(f))
3-element Vector{Vector{Int64}}:
[3, 1]
[1, 2]
[0, 0]
```

### Changing base (coefficient) rings

In order to substitute the variables of a polynomial $f$ over a ring $T$ by elements in a $T$-algebra $S$, you first have to change the base ring of $f$ using the following function, where $g$ is a function representing the structure homomorphism of the $T$-algebra $S$.

`change_base_ring`

— Method`change_base_ring(R::Ring, p::MPolyElem{<: RingElement}; parent::MPolyRing, cached::Bool)`

Return the polynomial obtained by coercing the non-zero coefficients of `p`

into `R`

.

If the optional `parent`

keyword is provided, the polynomial will be an element of `parent`

. The caching of the parent object can be controlled via the `cached`

keyword argument.

`change_coefficient_ring`

— Method`change_coefficient_ring(R::Ring, p::MPolyElem{<: RingElement}; parent::MPolyRing, cached::Bool)`

Return the polynomial obtained by coercing the non-zero coefficients of `p`

into `R`

.

If the optional `parent`

keyword is provided, the polynomial will be an element of `parent`

. The caching of the parent object can be controlled via the `cached`

keyword argument.

`map_coefficients`

— Method`map_coefficients(f, p::MPolyElem{<: RingElement}; parent::MPolyRing)`

Transform the polynomial `p`

by applying `f`

on each non-zero coefficient.

If the optional `parent`

keyword is provided, the polynomial will be an element of `parent`

. The caching of the parent object can be controlled via the `cached`

keyword argument.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> fz = x^2*y^2 + x + 1
x^2*y^2 + x + 1
julia> fq = change_base_ring(QQ, fz)
x^2*y^2 + x + 1
julia> fq = change_coefficient_ring(QQ, fz)
x^2*y^2 + x + 1
```

In case a specific parent ring is constructed, it can also be passed to the function.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> S, = PolynomialRing(QQ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Rationals, AbstractAlgebra.Generic.MPoly{Rational{BigInt}}[x, y])
julia> fz = x^5 + y^3 + 1
x^5 + y^3 + 1
julia> fq = change_base_ring(QQ, fz, parent=S)
x^5 + y^3 + 1
```

### Multivariate coefficients

In order to return the "coefficient" (as a multivariate polynomial in the same ring), of a given monomial (in which some of the variables may not appear and others may be required to appear to exponent zero), we can use the following function.

`coeff`

— Method`coeff(a::AbstractAlgebra.MPolyElem{T}, vars::Vector{Int}, exps::Vector{Int}) where T <: RingElement`

Return the "coefficient" of $a$ (as a multivariate polynomial in the same ring) of the monomial consisting of the product of the variables of the given indices raised to the given exponents (note that not all variables need to appear and the exponents can be zero). E.g. `coeff(f, [1, 3], [0, 2])`

returns the coefficient of $x^0*z^2$ in the polynomial $f$ (assuming variables $x, y, z$ in that order).

`coeff`

— Method`coeff(a::T, vars::Vector{T}, exps::Vector{Int}) where T <: AbstractAlgebra.MPolyElem`

Return the "coefficient" of $a$ (as a multivariate polynomial in the same ring) of the monomial consisting of the product of the given variables to the given exponents (note that not all variables need to appear and the exponents can be zero). E.g. `coeff(f, [x, z], [0, 2])`

returns the coefficient of $x^0*z^2$ in the polynomial $f$.

**Examples**

```
julia> R, (x, y, z) = PolynomialRing(ZZ, ["x", "y", "z"])
(Multivariate Polynomial Ring in x, y, z over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y, z])
julia> f = x^4*y^2*z^2 - 2x^4*y*z^2 + 4x^4*z^2 + 2x^2*y^2 + x + 1
x^4*y^2*z^2 - 2*x^4*y*z^2 + 4*x^4*z^2 + 2*x^2*y^2 + x + 1
julia> coeff(f, [1, 3], [4, 2]) == coeff(f, [x, z], [4, 2])
true
```

### Inflation/deflation

`deflation`

— Method`deflation(f::AbstractAlgebra.MPolyElem{T}) where T <: RingElement`

Compute deflation parameters for the exponents of the polynomial $f$. This is a pair of arrays of integers, the first array of which (the shift) gives the minimum exponent for each variable of the polynomial, and the second of which (the deflation) gives the gcds of all the exponents after subtracting the shift, again per variable. This functionality is used by gcd (and can be used by factorisation algorithms).

`deflate`

— Method`deflate(f::AbstractAlgebra.MPolyElem{T}, shift::Vector{Int}, defl::Vector{Int}) where T <: RingElement`

Return a polynomial with the same coefficients as $f$ but whose exponents have been reduced by the given shifts (supplied as an array of shifts, one for each variable), then deflated (divided) by the given exponents (again supplied as an array of deflation factors, one for each variable). The algorithm automatically replaces a deflation of $0$ by $1$, to avoid division by $0$.

`deflate`

— Method`deflate(f::AbstractAlgebra.MPolyElem{T}, defl::Vector{Int}) where T <: RingElement`

Return a polynomial with the same coefficients as $f$ but whose exponents have been deflated (divided) by the given exponents (supplied as an array of deflation factors, one for each variable).

The algorithm automatically replaces a deflation of $0$ by $1$, to avoid division by $0$.

`deflate`

— Method`deflate(f::AbstractAlgebra.MPolyElem{T}, defl::Vector{Int}) where T <: RingElement`

Return a polynomial with the same coefficients as $f$ but whose exponents have been deflated maximally, i.e. with each exponent divide by the largest integer which divides the degrees of all exponents of that variable in $f$.

`deflate`

— Method`deflate(f::AbstractAlgebra.MPolyElem, vars::Vector{Int}, shift::Vector{Int}, defl::Vector{Int})`

Return a polynomial with the same coefficients as $f$ but where exponents of some variables (supplied as an array of variable indices) have been reduced by the given shifts (supplied as an array of shifts), then deflated (divided) by the given exponents (again supplied as an array of deflation factors). The algorithm automatically replaces a deflation of $0$ by $1$, to avoid division by $0$.

`deflate`

— Method`deflate(f::T, vars::Vector{T}, shift::Vector{Int}, defl::Vector{Int}) where T <: AbstractAlgebra.MPolyElem`

Return a polynomial with the same coefficients as $f$ but where the exponents of the given variables have been reduced by the given shifts (supplied as an array of shifts), then deflated (divided) by the given exponents (again supplied as an array of deflation factors). The algorithm automatically replaces a deflation of $0$ by $1$, to avoid division by $0$.

`inflate`

— Method`inflate(f::AbstractAlgebra.MPolyElem{T}, shift::Vector{Int}, defl::Vector{Int}) where T <: RingElement`

Return a polynomial with the same coefficients as $f$ but whose exponents have been inflated (multiplied) by the given deflation exponents (supplied as an array of inflation factors, one for each variable) and then increased by the given shifts (again supplied as an array of shifts, one for each variable).

`inflate`

— Method`inflate(f::AbstractAlgebra.MPolyElem{T}, defl::Vector{Int}) where T <: RingElement`

Return a polynomial with the same coefficients as $f$ but whose exponents have been inflated (multiplied) by the given deflation exponents (supplied as an array of inflation factors, one for each variable).

`inflate`

— Method`inflate(f::AbstractAlgebra.MPolyElem, vars::Vector{Int}, shift::Vector{Int}, defl::Vector{Int})`

Return a polynomial with the same coefficients as $f$ but where exponents of some variables (supplied as an array of variable indices) have been inflated (multiplied) by the given deflation exponents (supplied as an array of inflation factors) and then increased by the given shifts (again supplied as an array of shifts).

`inflate`

— Method`inflate(f::T, vars::Vector{T}, shift::Vector{Int}, defl::Vector{Int}) where T <: AbstractAlgebra.MPolyElem`

Return a polynomial with the same coefficients as $f$ but where the exponents of the given variables have been inflated (multiplied) by the given deflation exponents (supplied as an array of inflation factors) and then increased by the given shifts (again supplied as an array of shifts).

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = x^7*y^8 + 3*x^4*y^8 - x^4*y^2 + 5x*y^5 - x*y^2
x^7*y^8 + 3*x^4*y^8 - x^4*y^2 + 5*x*y^5 - x*y^2
julia> def, shift = deflation(f)
([1, 2], [3, 3])
julia> f1 = deflate(f, def, shift)
x^2*y^2 + 3*x*y^2 - x + 5*y - 1
julia> f2 = inflate(f1, def, shift)
x^7*y^8 + 3*x^4*y^8 - x^4*y^2 + 5*x*y^5 - x*y^2
julia> f2 == f
true
julia> g = (x+y+1)^2
x^2 + 2*x*y + 2*x + y^2 + 2*y + 1
julia> g0 = coeff(g, [y], [0])
x^2 + 2*x + 1
julia> g1 = deflate(g - g0, [y], [1], [1])
2*x + y + 2
julia> g == g0 + y * g1
true
```

### Conversions

`to_univariate`

— Method`to_univariate(R::AbstractAlgebra.PolyRing{T}, p::AbstractAlgebra.MPolyElem{T}) where T <: AbstractAlgebra.RingElement`

Assuming the polynomial $p$ is actually a univariate polynomial, convert the polynomial to a univariate polynomial in the given univariate polynomial ring $R$. An exception is raised if the polynomial $p$ involves more than one variable.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> S, z = PolynomialRing(ZZ, "z")
(Univariate Polynomial Ring in z over Integers, z)
julia> f = 2x^5 + 3x^4 - 2x^2 - 1
2*x^5 + 3*x^4 - 2*x^2 - 1
julia> g = to_univariate(S, f)
2*z^5 + 3*z^4 - 2*z^2 - 1
```

### Evaluation

The following function allows evaluation of a polynomial at all its variables. The result is always in the ring that a product of a coefficient and one of the values belongs to, i.e. if all the values are in the coefficient ring, the result of the evaluation will be too.

`evaluate`

— Method`evaluate(a::AbstractAlgebra.MPolyElem{T}, vals::Vector{U}) where {T <: RingElement, U <: RingElement}`

Evaluate the polynomial expression by substituting in the array of values for each of the variables. The evaluation will succeed if multiplication is defined between elements of the coefficient ring of $a$ and elements of the supplied vector.

The following functions allow evaluation of a polynomial at some of its variables. Note that the result will be a product of values and an element of the polynomial ring, i.e. even if all the values are in the coefficient ring and all variables are given values, the result will be a constant polynomial, not a coefficient.

`evaluate`

— Method`evaluate(a::AbstractAlgebra.MPolyElem{T}, vars::Vector{Int}, vals::Vector{U}) where {T <: RingElement, U <: RingElement}`

Evaluate the polynomial expression by substituting in the supplied values in the array `vals`

for the corresponding variables with indices given by the array `vars`

. The evaluation will succeed if multiplication is defined between elements of the coefficient ring of $a$ and elements of `vals`

.

`evaluate`

— Method`evaluate(a::S, vars::Vector{S}, vals::Vector{U}) where {S <: AbstractAlgebra.MPolyElem{T}, U <: RingElement} where T <: RingElement`

Evaluate the polynomial expression by substituting in the supplied values in the array `vals`

for the corresponding variables (supplied as polynomials) given by the array `vars`

. The evaluation will succeed if multiplication is defined between elements of the coefficient ring of $a$ and elements of `vals`

.

The following function allows evaluation of a polynomial at values in a not necessarily commutative ring, e.g. elements of a matrix algebra.

`evaluate`

— Method`evaluate(a::AbstractAlgebra.MPolyElem{T}, vals::Vector{U}) where {T <: RingElement, U <: NCRingElem}`

Evaluate the polynomial expression at the supplied values, which may be any ring elements, commutative or non-commutative, but in the same ring. Evaluation always proceeds in the order of the variables as supplied when creating the polynomial ring to which $a$ belongs. The evaluation will succeed if a product of a coefficient of the polynomial by one of the values is defined.

**Examples**

```
julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = 2x^2*y^2 + 3x + y + 1
2*x^2*y^2 + 3*x + y + 1
julia> evaluate(f, BigInt[1, 2])
14
julia> evaluate(f, [QQ(1), QQ(2)])
14//1
julia> evaluate(f, [1, 2])
14
julia> f(1, 2) == 14
true
julia> evaluate(f, [x + y, 2y - x])
2*x^4 - 4*x^3*y - 6*x^2*y^2 + 8*x*y^3 + 2*x + 8*y^4 + 5*y + 1
julia> f(x + y, 2y - x)
2*x^4 - 4*x^3*y - 6*x^2*y^2 + 8*x*y^3 + 2*x + 8*y^4 + 5*y + 1
julia> R, (x, y, z) = PolynomialRing(ZZ, ["x", "y", "z"])
(Multivariate Polynomial Ring in x, y, z over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y, z])
julia> f = x^2*y^2 + 2x*z + 3y*z + z + 1
x^2*y^2 + 2*x*z + 3*y*z + z + 1
julia> evaluate(f, [1, 3], [3, 4])
9*y^2 + 12*y + 29
julia> evaluate(f, [x, z], [3, 4])
9*y^2 + 12*y + 29
julia> evaluate(f, [1, 2], [x + z, x - z])
x^4 - 2*x^2*z^2 + 5*x*z + z^4 - z^2 + z + 1
julia> S = MatrixAlgebra(ZZ, 2)
Matrix Algebra of degree 2 over Integers
julia> M1 = S([1 2; 3 4])
[1 2]
[3 4]
julia> M2 = S([2 3; 1 -1])
[2 3]
[1 -1]
julia> M3 = S([-1 1; 1 1])
[-1 1]
[ 1 1]
julia> evaluate(f, [M1, M2, M3])
[ 64 83]
[124 149]
```

### Leading and constant coefficients, leading monomials and leading terms

The leading and trailing coefficient, constant coefficient, leading monomial and leading term of a polynomial p are returned by the following functions:

`leading_coefficient`

— Method`leading_coefficient(p::MPolyElem)`

Return the leading coefficient of the polynomial $p$.

`trailing_coefficient`

— Method`trailing_coefficient(p::MPolyElem)`

Return the trailing coefficient of the polynomial $p$, i.e. the coefficient of the last nonzero term, or zero if the polynomial is zero.

`leading_monomial`

— Method`leading_monomial(p::MPolyElem)`

Return the leading monomial of $p$. This function throws an `ArgumentError`

if $p$ is zero.

`leading_term`

— Method`leading_term(p::MPolyElem)`

Return the leading term of the polynomial p. This function throws an `ArgumentError`

if $p$ is zero.

`constant_coefficient`

— Method`constant_coefficient(p::MPolyElem)`

Return the constant coefficient of the polynomial $p$ or zero if it doesn't have one.

`tail`

— Method`tail(p::MPolyElem)`

Return the tail of the polynomial $p$, i.e. the polynomial without its leading term (if any).

**Examples**

```
using AbstractAlgebra
R,(x,y) = PolynomialRing(ZZ, ["x", "y"], ordering=:deglex)
p = 2*x*y + 3*y^3 + 1
leading_term(p)
leading_monomial(p)
leading_coefficient(p)
leading_term(p) == leading_coefficient(p) * leading_monomial(p)
constant_coefficient(p)
tail(p)
```

### Least common multiple, greatest common divisor

The greatest common divisor of two polynomials a and b is returned by

`gcd`

— Method`gcd(a::MPoly{T}, a::MPoly{T}) where {T <: RingElement}`

Return the greatest common divisor of a and b in parent(a).

Note that this functionality is currently only provided for AbstractAlgebra generic polynomials. It is not automatically provided for all multivariate rings that implement the multivariate interface.

However, if such a gcd is provided, the least common multiple of two polynomials a and b is returned by

`lcm`

— Method`lcm(a::AbstractAlgebra.MPolyElem{T}, a::AbstractAlgebra.MPolyElem{T}) where {T <: RingElement}`

Return the least common multiple of a and b in parent(a).

**Examples**

```
julia> using AbstractAlgebra
julia> R,(x,y) = PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> a = x*y + 2*y
x*y + 2*y
julia> b = x^3*y + y
x^3*y + y
julia> gcd(a,b)
y
julia> lcm(a,b)
x^4*y + 2*x^3*y + x*y + 2*y
julia> lcm(a,b) == a * b // gcd(a,b)
true
```

### Derivations

`derivative`

— Method`derivative(f::AbstractAlgebra.MPolyElem{T}, x::AbstractAlgebra.MPolyElem{T}) where T <: RingElement`

Return the partial derivative of `f`

with respect to `x`

. The value `x`

must be a generator of the polynomial ring of `f`

.

**Examples**

```
julia> R, (x, y) = AbstractAlgebra.PolynomialRing(ZZ, ["x", "y"])
(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])
julia> f = x*y + x + y + 1
x*y + x + y + 1
julia> derivative(f, x)
y + 1
julia> derivative(f, y)
x + 1
julia> derivative(f, 1)
y + 1
julia> derivative(f, 2)
x + 1
```

### Homogeneous polynomials

It is possible to test whether a polynomial is homogeneous with respect to the standard grading using the function

`is_homogeneous`

— Method`is_homogeneous(x::MPoly{T}) where {T <: RingElement}`

Return `true`

if the given polynomial is homogeneous with respect to the standard grading and `false`

otherwise.

## Random generation

Random multivariate polynomials in a given ring can be constructed by passing a range of degrees for the variables and a range on the number of terms. Additional parameters are used to generate the coefficients of the polynomial.

Note that zero coefficients may currently be generated, leading to less than the requested number of terms.

`rand(R::MPolyRing, exp_range::UnitRange{Int}, term_range::UnitRange{Int}, v...)`

**Examples**

`julia> R, (x, y) = PolynomialRing(ZZ, ["x", "y"])`

`(Multivariate Polynomial Ring in x, y over Integers, AbstractAlgebra.Generic.MPoly{BigInt}[x, y])`

`julia> f = rand(R, -1:2, 3:5, -10:10)`

`0`

`julia> S, (s, t) = PolynomialRing(GF(7), ["x", "y"])`

`(Multivariate Polynomial Ring in x, y over Finite field F_7, AbstractAlgebra.Generic.MPoly{AbstractAlgebra.GFElem{Int64}}[x, y])`

`julia> g = rand(S, -1:2, 3:5)`

`0`